Autor Thema: Fastram mit PAK68/2 ...  (Gelesen 43293 mal)

0 Mitglieder und 1 Gast betrachten dieses Thema.

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #100 am: Mi 08.03.2017, 13:27:06 »
Habe nur einen Mega ST4 mit TOS 1.04 auf dem Board. Könnte aber EmuTOS drauf machen. Eine TOS 2.06 Karte habe ich nicht.

Habe ein gepatchtes PAK68/3 TOS 3.06 auf der PAK da ich davon ausgebe das TOS 2.06 mit Fastram nicht umgehen kann.

Ich könnte mir auch bei Kessler die 512kB SRAMs kaufen aber ist dieses BANK0 und BANK1 nicht für insgesamt 8 SRAMs also im Falle der 512er 2MB in BANK0 und weitere 4 Stk. in BANK1 also insgesamt dann 4MB Fastram ?

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #101 am: Mi 08.03.2017, 15:40:02 »
Alles mit "ja" zu beantworten.
Da TOS 3.06 beim Start das FastRam auch auf Spiegelungen (an nicht ausdekodierten Adressleitungen ) etc. testet, also tatsächlich Schreib- und Lese-Zugriffe tätigt, reicht eine minimale Dekodierung des FastRAM, hier nur mit A24. Der Buserror beim FastRAM-Zugriff oberhalb 1 MB Fastram, wie von mir in U6 eingefügt, ist eigentlich überflüssig/ unnötig, bzw. bei Deinem 16MB Atari-TT-FastRAM hinderlich. Aber das kann dann ja in einem  weiteren Schritt geändert werden.

Wenn Du nun nur eine Bank SRAMs einsetzt, bemerkt TOS 3.06 das, und bindet auch nur die eine Bank ein.
Ich kenne EMUTOS (noch) nicht, bin lange 'raus aus dem Thema.
Das originale U12 erzeugt nur /DSACK0 und /DSACK1 für 32bittigen ROM-Zugriff; 8 und 16bitige FastRAM Zugriffe werden falsch beendet, das funktioniert nicht. Hier kommt die Dekodierung nach "AMIGA-Muster" aus 1992 ins Spiel.

Für das TT-FastRAM müsste die STERM_nach DSACK-Dioden-Lösung her, oder eine weitere Verarbeitung von /STERM im GAL. Damit gehen dann auch nur 32bit-Zugriffe korrekt.
Macht aber ev. nix, da das Tos 3.06 auf das TTFastRam offenbar (siehe /STERM) nur 32bittig zugreift?!

Wenn Du weiterhin die TTFastRAM-Karte testen möchtest und eine Zyklus-Terminierung realisieren willst, dann muss etwas her wie oben beschrieben, oder besser mit A24 (s. U12_froam.pds/jed aus dem alten Thread). Ein erster Test könnte auch sein, in Deinem U12
Zitat
case ( a[24..16] ) begin
 #h0E0..#h0EF:
   begin
     cs11 = as_20 * /cpuspace
     cs10 = as_20 * /cpuspace
     cs9  = as_20 * /cpuspace
     cs8  = as_20 * /cpuspace
   end
 otherwise
   case ( a[24..16] ) begin
 #h100..#h1FF:
   begin
     cs11 = as_20 * /cpuspace
     cs10 = as_20 * /cpuspace
     cs9  = as_20 * /cpuspace
     cs8  = as_20 * /cpuspace
   end
   otherwise
     begin
        cs11 = gnd
        cs10 = gnd
        cs9  = gnd
       cs8  = gnd
     end
end

dsack0.trst = cs11
dsack1.trst = cs11

dsack0 = as_20 ;
dsack1 = as_20 ;
Edit: das ist Quatsch so! reicht allenfalls als Denkanstoß :-[

Also auch nur 32bit /DSACKx.
Ob das so übersetzt werden kann .. keine Ahnung, ich hatte eben damals die  korrekte Variante mit /siz0 und /siz1 verwendet.
Da das Kessler RAM ja viermal soviel RAM hat wie die von mir verendeten SRAMs muss auch das Pin-Out und die BANK-Logic überprüft werden.
« Letzte Änderung: Mi 08.03.2017, 17:21:51 von joejoe »

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #102 am: Mi 08.03.2017, 17:05:44 »
Das hier war die "letzte" Variante von U12:
Zitat
;PALASM Design Description
;
;  (c) M.V”lkel  GK _Computer Freiburg
;
;   Address Decoder fr On Board Speicher  FAST-RAM
;
;
;    Fr ATARI ST   0100 0000-0107 FFFF   TT-Fast-Ram
;    4.11.93
;    rom_bank
;    5.9.94
;    12.12.94 JP3 entfernt, ram_1 auf PIN 23 gelegt
;    03.03.95
;    Version fr TOS X.06 Autoboot mit TOS X.06-Anfang auf Mainboard
;    Resetvektoren zeigen auf E0 0000.

;------------------------------------------------------------------------
;---------------------------------- Declaration Segment ------------
TITLE    FROAM
PATTERN  P20-20 = U12_FASTRAM
REVISION 1
AUTHOR   Manfred V”lkel ge„ndert J.Reinecke c't 10/92 AMIGA-Muster
COMPANY  GK Computer
DATE     06/01/91

CHIP  _p20_20n  PALCE22V10

;---------------------------------- PIN Declarations ---------------

PIN  1          /as_20     COMBINATORIAL ; INPUT
PIN  2          /cpuspace  COMBINATORIAL ; INPUT
PIN  3          siz0       COMBINATORIAL ; INPUT
PIN  4          siz1       COMBINATORIAL ; INPUT
PIN  5          a[24]      COMBINATORIAL ; INPUT  !!!! VORHER: a[18] !!!!!
PIN  6..10      a[19..23]  COMBINATORIAL ; INPUT
PIN  11         a1         COMBINATORIAL ; INPUT  !!!! VORHER: a[29] !!!
PIN  12         GND
PIN  13         a0         COMBINATORIAL ; INPUT  !!!! VORHER: a[30] !!!
PIN  14         /rom       COMBINATORIAL ; OUTPUT !!!! VORHER:    a1 !!!!
PIN  15         ram_0      COMBINATORIAL ; OUTPUT !!!! VORHER:    a0 !!!!
PIN  16         rw         COMBINATORIAL ; INPUT  !!!! VORHER  a[16] !!!!
PIN  17         /cs11      COMBINATORIAL ; OUTPUT
PIN  18         /cs10      COMBINATORIAL ; OUTPUT
PIN  19         /cs9       COMBINATORIAL ; OUTPUT
PIN  20         /cs8       COMBINATORIAL ; OUTPUT
PIN  21         dsack_en   COMBINATORIAL ; OUTPUT !!!! VORHER: /dsack1 !!!!
PIN  22         /dsack0    COMBINATORIAL ; OUTPUT
PIN  23         ram_1      COMBINATORIAL ; OUTPUT !!!! VORHER: a[17] !!!!
PIN  24         VCC

; die PINs ram_0, ram_1 werden mit den nun abgebogenen PINs CE2 (PIN 30)
; der statischen RAMs verbunden, ram_0 geht an die unteren, ram_1  an die
; oberen 512 kB (alle RAMs einer Bank am PIN 30 miteinander verbinden)
; /rom geht an /OE (PIN 22) der EPROMS, /CE (PIN 20) der EPROMs im Sockel
; auf GND -> schneller Lesezugriff m”glich
; /dsack1 (alter Pin 21) im Adaptersockel wird durch Schottkydiode mit
; /dsack0 (PIN 22) verbunden (Kathode an PIN 22); PIN 21 GAL wird umgebogen
; bleibt unbelegt (notwendig fr ODER-Verknpfung in /dsack0)
; rw (PIN 16 GAL) wird mit R/W verbunden; notwendig fr 68030 Caches



string uucs   '(  /a0 * /a1 ) '
string umcs   '(  /a1*siz1 + a0*/a1 + /a1*/siz0 )'
string lmcs   '(  a0*/a1*/siz0 + /a1*siz0*siz1 + /a1*/siz0*/siz1 + /a0*a1 )'
string llcs   '(  a1*siz1 + a0*a1 + /siz0*/siz1 + a0*siz0*siz1 )'
string fram   '(  a[24] * /a[23] * /a[22] * /a[21] * /a[20] )'; 1 MB
string tosx06 '( /a[24] *  a[23] *  a[22] *  a[21] * /a[20] )'; 0E0000 - 0EFFFF

;----------------------------------- Boolean Equation Segment ------
EQUATIONS



MINIMIZE_ON


cs11  = as_20 * /cpuspace * (uucs + rw);

cs10  = as_20 * /cpuspace * (umcs + rw);

cs9   = as_20 * /cpuspace * (lmcs + rw);

cs8   = as_20 * /cpuspace * (llcs + rw);

ram_0 = /a[19] * fram;

ram_1 =  a[19] * fram;

rom   = as_20 * /cpuspace * tosx06;

dsack_en =  as_20 * /cpuspace  * (rom + fram);

dsack0.trst = dsack_en;

dsack0  = as_20;
Es ist dringend ein 22V10 notwendig, ein 20V8 hat nicht genug "Power".
Die Umbelegungen im PIN-OUT waren notwendig, um ausreichend Ausgänge frei zu schaufeln, indem iNPUT-Signale, welche ursprünglich an (im 22V10) potentiellen Ausgängen verdrahtet waren auf dedizierte INPUT-Pin verlegt wurden. Hier nicht benötigte Eingänge wurden umbelegt.
Der Text im PDS sollte weitere Fragen klären.
Ich hatte mir Türmchen aus Sockeln und GALs mit aufgelöteten Sockeln gebaut, um die Verdrahtung in weitrenen, modifizierten Zwischensockeln variabel gestalten zu können und keine GAL-Pins hin- (für die PAK)  und her (zum Programmieren) biegen zu müssen.

Als Starter-ROMs "unten" auf dem ST hatte ich zwei 256kB-ROMs mit den entsprechenden (unmodifizierten) unteren HI-/LO-Teilen von TOS 2.06. Das ist zwar allein nicht lauffähig, startet dann aber ab nach E0...
Gruß und viel Erfolg
joe

EDIT: es war das gepatchte 3.06
« Letzte Änderung: So 16.04.2017, 13:13:35 von joejoe »

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #103 am: Mi 08.03.2017, 17:10:58 »
und noch das jedec-file:


btw. wie übersetzt Du die PDS-Files?
Die hier verwendete Schreibweise funktioniert nur mit PALASM, nicht mit den ATARI GAL-Assemblern (die mir damals bekannt waren)

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #104 am: Mi 08.03.2017, 17:28:53 »
Wenn Du keine SRAMs einsetzt, reichen die Ausgänge eines 20V8 ev. auch. Dann musst Du auch die vielen Umbelegungen nicht durchführen, und könntest Dir dennoch das DSACK0/1 erzeugen.
Sehe eben, dass meine Ausführungen zu den 8-/16-/32-bit Zugriffen im Zusammenhang mit den DSACKs immer noch genauso falsch sind, wie von czietz im alten Thread schon angemerkt. Die Dekodierung der /CS per siz0/1 ist wichtig.
siehe auch mein U12. ;) 8)
« Letzte Änderung: Mi 08.03.2017, 18:41:50 von joejoe »

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #105 am: Mi 08.03.2017, 17:37:50 »
Ich hatte mal PALASM unter DOSBOX installiert aber komme damit nicht zurecht. Muss mal Google bemühen und nach einem Handbuch suchen ...

Ich würde lieber JEDI auf dem Atari nutzen aber der kann soweit ich weiß keine 22V10 und ich weiß nicht ob ich es hin bekomme die PDS Quellen in JEDI umzusetzen.

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #106 am: Mi 08.03.2017, 18:01:39 »
Okay,
wichtig ist bei den PALASM Quellen, dass die Polarität (positive oder negative Logik) eines INPUT oder OUTPUT in der PIN-Deklaration festgelegt wird.
Der Text auf der linken Seite der Gleichungen legt nur den Zustand fest (TRUE / FALSE), unabhängig, ob positive oder negative Logik verwendet wird. Das war bei den ATARI PAL/GAL-Assemblern anders!

Als Beispiel:
cycle_00 in U6 ist in den PIN-Definitionen als negative Logik definiert (WAHR bei Low),gekennzeichnet durch den Negations-Strich "/"
Wenn nun in denLogik-Gleichungen auf der linken Seite cycle_00 steht, dann ist der Ausgang WAHR (= low, siehe PIN-Definition!) wenn die rechte Seite WAHR wird.
Für Jedi muss das dann alles _passend_ umgestellt werden.

Nur zur Info, falls das jemand nicht weiß, und sich wundert warum es mit PASASM oder Jedi vice versa nicht so einfach klappt.
Gruß
joe
« Letzte Änderung: Mi 08.03.2017, 20:40:31 von joejoe »

Offline 1ST1

  • Benutzer
  • Beiträge: 8.661
  • Gesperrter User
Re: Fastram mit PAK68/2 ...
« Antwort #107 am: Mi 08.03.2017, 19:40:50 »
TOS 2.06 läuft wunderbar mit der PAK 68/2. Aber TOS 2.06 sucht nicht nach TT-RAM.
Ausgeloggter Mitleser, der hier NIE mehr aktiv wird. Am besten, meine Inhalte komplett löschen. Dabei berufe ich mich auf mein Urheberrecht, die DSGVO und auf die Rechte, die mir unter Impressunm&Datenschutz zugestanden werden. Tschö!

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #108 am: Mi 08.03.2017, 19:53:44 »
TOS 2.06 läuft wunderbar mit der PAK 68/2. Aber TOS 2.06 sucht nicht nach TT-RAM.

Ein wenig OT .

Hat ja niemand behauptet TOS 2.06 liefe nicht auf PAK, wegen dem Fastram nutze ich wie schon gesagt TOS 3.06 von der PAK68/3 ...

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #109 am: Mi 08.03.2017, 22:45:03 »
Habe zur Zeit auch kein PALASM installiert;

anbei ein U12.PDS wie ich es mir für Deine Atari-FastramKarte vorstelle:
Für ein 20V8 und mit a[24] anstelle von a[29]

Zitat
;PALASM Design Description
;
;  (c) M.Völkel  GK _Computer Freiburg
;
;   Address Decoder für On Board Speicher  EPROM und DSACK0/1 ATARI-TT-FastRAM
;
;
;    Für ATARI ST   E00000-EFFFFF              für TOS030
;    und DSACK0/1 im Bereich 100 0000 bis 1FF FFFF = 16MByte ATARI-TT-FastRAM
;
;------------------------------------------------------------------------
;---------------------------------- Declaration Segment ------------
TITLE    68020-16 PAK
PATTERN  P20-24
REVISION 1
AUTHOR   Manfred Völkel, modified J.Reinecke 03/2017
COMPANY  GK Computer
DATE     06/01/91

CHIP  _p20_24  PALCE20V8

;---------------------------------- PIN Declarations ---------------

PIN  1          /as_20                                COMBINATORIAL ; INPUT
PIN  2          /cpuspace                             COMBINATORIAL ; INPUT
PIN  3          siz0                                  COMBINATORIAL ; INPUT
PIN  4          siz1                                  COMBINATORIAL ; INPUT
PIN  5..10      a[18..23]                             COMBINATORIAL ; INPUT
PIN  11         a[24]                                 COMBINATORIAL ; INPUT (war a[29])
PIN  12         GND                                              ; INPUT
PIN  13         a[30]                                 COMBINATORIAL ; INPUT
PIN  14         a1                                    COMBINATORIAL ; INPUT
PIN  15         a0                                    COMBINATORIAL ; INPUT
PIN  16         a[16]                                 COMBINATORIAL ; INPUT
PIN  17         /cs11                                 COMBINATORIAL ; OUTPUT
PIN  18         /cs10                                 COMBINATORIAL ; OUTPUT
PIN  19         /cs9                                  COMBINATORIAL ; OUTPUT
PIN  20         /cs8                                  COMBINATORIAL ; OUTPUT
PIN  21         /dsack1                               COMBINATORIAL ; OUTPUT
PIN  22         /dsack0                               COMBINATORIAL ; OUTPUT
PIN  23         a[17]                                 COMBINATORIAL ; INPUT
PIN  24         VCC                                              ;       

;----------------------------------- Boolean Equation Segment ------
EQUATIONS

MINIMIZE_ON

string uucs   '(  /a0 * /a1 ) '
string umcs   '(  /a1*siz1 + a0*/a1 + /a1*/siz0 )'
string lmcs   '(  a0*/a1*/siz0 + /a1*siz0*siz1 + /a1*/siz0*/siz1 + /a0*a1 )'
string llcs   '(  a1*siz1 + a0*a1 + /siz0*/siz1 + a0*siz0*siz1 )'
string fram   '(  a[24])'                             ; 16 MB
string tosx06 '( /a[24] *  a[23] *  a[22] *  a[21] * /a[20] )'; 0E0000 - 0EFFFF

;----------------------------------- Boolean Equation Segment ------
EQUATIONS



MINIMIZE_ON


cs11  = as_20 * /cpuspace * uucs * tosx06;

cs10  = as_20 * /cpuspace * umcs * tosx06;

cs9   = as_20 * /cpuspace * lmcs * tosx06;

cs8   = as_20 * /cpuspace * llcs * tosx06;

dsack_en =  as_20 * /cpuspace  * (tosx06 + fram);

dsack0.trst = dsack_en;
dsack1.trst = dsack_en;

dsack0  = as_20;
dsack1  = as_20;

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #110 am: Do 09.03.2017, 10:35:07 »
Ich komme nicht klar ...

--- U12_24.LCI (JEDI) ---

U12_24  Addressdekoder fr TOS 2.06 ROMs auf der PAK 68/2 fr Atari ST

08-03-93   U12_24     aus P20_24 recompiliert, GAL-ID hinzu

                               ___  ___
                                 |   \/   |
                     !as_20 |1     24| VCC
    (cpuspace)   !csp |2     23| a17
                         siz0 |3     22| !dsack0
                         siz1 |4     21| !dsack1
                         a18 |5     20| !cs8
                         a19 |6     19| !cs9
                         a20 |7     18| !cs10
                         a21 |8     17| !cs11
                         a22 |9     16| a16
                         a23 |10    15| a0       (nicht als Input nutzbar)
                         a24 |11    14| a1
                       GND |12    13| a30
                              |________|

%ID
   U12_24
%TYP
   GAL20V8A
%PINS
   !as_20  !csp  siz0  siz1  a18    a19    a20   a21   a22      a23      a24
   a30     a1     a16   a0    !cs11  !cs10  !cs9  !cs8  !dsack1  !dsack0  a17
%LOGIC

   dsack0.OE = cs11;
   dsack0    = as_20;

   dsack1.OE = cs11;
   dsack1    = as_20;

   cs8.OE    = VCC;
   cs8       = !csp * as_20 * !a24 * a23 * a22 * a21 * !a20;

   cs9.OE    = VCC;
   cs9       = !csp * as_20 * !a24 * a23 * a22 * a21 * !a20;

   cs10.OE   = VCC;
   cs10      = !csp * as_20 * !a24 * a23 * a22 * a21 * !a20;

   cs11.OE   = VCC;
   cs11      = !csp * as_20 * !a24 * a23 * a22 * a21 * !a20;

   a16.OE    = GND;

   a0.OE     = GND;

%END

------------------------------------
Wie baue ich jetzt FRAM da ein und was ist mit uucs, umcs, lmcs, llcs  ?

------------------------------------
;PALASM Design Description
;
;  (c) M.Völkel  GK _Computer Freiburg
;
;   Address Decoder für On Board Speicher  EPROM und DSACK0/1 ATARI-TT-FastRAM
;
;
;    Für ATARI ST   E00000-EFFFFF              für TOS030
;    und DSACK0/1 im Bereich 100 0000 bis 1FF FFFF = 16MByte ATARI-TT-FastRAM
;
;------------------------------------------------------------------------
;---------------------------------- Declaration Segment ------------
TITLE    68020-16 PAK
PATTERN  P20-24
REVISION 1
AUTHOR   Manfred Völkel, modified J.Reinecke 03/2017
COMPANY  GK Computer
DATE     06/01/91

CHIP  _p20_24  PALCE20V8

;---------------------------------- PIN Declarations ---------------

PIN  1          /as_20                                COMBINATORIAL ; INPUT
PIN  2          /cpuspace                             COMBINATORIAL ; INPUT
PIN  3          siz0                                  COMBINATORIAL ; INPUT
PIN  4          siz1                                  COMBINATORIAL ; INPUT
PIN  5..10      a[18..23]                             COMBINATORIAL ; INPUT
PIN  11         a[24]                                 COMBINATORIAL ; INPUT (war a[29])
PIN  12         GND                                              ; INPUT
PIN  13         a[30]                                 COMBINATORIAL ; INPUT
PIN  14         a1                                    COMBINATORIAL ; INPUT
PIN  15         a0                                    COMBINATORIAL ; INPUT
PIN  16         a[16]                                 COMBINATORIAL ; INPUT
PIN  17         /cs11                                 COMBINATORIAL ; OUTPUT
PIN  18         /cs10                                 COMBINATORIAL ; OUTPUT
PIN  19         /cs9                                  COMBINATORIAL ; OUTPUT
PIN  20         /cs8                                  COMBINATORIAL ; OUTPUT
PIN  21         /dsack1                               COMBINATORIAL ; OUTPUT
PIN  22         /dsack0                               COMBINATORIAL ; OUTPUT
PIN  23         a[17]                                 COMBINATORIAL ; INPUT
PIN  24         VCC                                              ;       

;----------------------------------- Boolean Equation Segment ------
EQUATIONS

MINIMIZE_ON

string uucs   '(  /a0 * /a1 ) '
string umcs   '(  /a1*siz1 + a0*/a1 + /a1*/siz0 )'
string lmcs   '(  a0*/a1*/siz0 + /a1*siz0*siz1 + /a1*/siz0*/siz1 + /a0*a1 )'
string llcs   '(  a1*siz1 + a0*a1 + /siz0*/siz1 + a0*siz0*siz1 )'
string fram   '(  a[24])'                             ; 16 MB
string tosx06 '( /a[24] *  a[23] *  a[22] *  a[21] * /a[20] )'; 0E0000 - 0EFFFF

;----------------------------------- Boolean Equation Segment ------
EQUATIONS



MINIMIZE_ON


cs11  = as_20 * /cpuspace * uucs * tosx06;

cs10  = as_20 * /cpuspace * umcs * tosx06;

cs9   = as_20 * /cpuspace * lmcs * tosx06;

cs8   = as_20 * /cpuspace * llcs * tosx06;

dsack_en =  as_20 * /cpuspace  * (tosx06 + fram);

dsack0.trst = dsack_en;
dsack1.trst = dsack_en;

dsack0  = as_20;
dsack1  = as_20;
« Letzte Änderung: Do 09.03.2017, 10:37:35 von Lukas Frank »

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #111 am: Do 09.03.2017, 16:44:42 »
Die Strings 'uucs','FastRAM'  etc. werden von PALASM beim Compilieren einfach erweitert, sobald der Compiler auf einen solchen String stößt.
Das konnte JEDI glaube ich nicht. Also einfach per copy und paste in die GAL-Gleichungen einfügen.

'uucs' etc, also die steuerung der byte/word/longword Zugriffe ist ohne SRAM für den einfachen Test mit Deiner TT-FastrAM-Karte aber gar nicht nötigt, das macht ja alles die FastRAM-MMU:

Damit FastRAM von normalem RAM bzw. ST-Adressbereich unterschieden werden kann, ist A24 nötig, und bei 16MB Fastram auch schon ausreichend, für eine vollständige Dekodierung der 16MB FastRAM (16 MByte = A0 bis A23)
Die  DSACKs kannst Du entweder hier (in U12) auch für die TT-FastRAM-Karte erzeugen, oder machst das per STERM irgendwie extern.

Eine eigene Variante von U12 für Deine FAstRAM-Karte ist nur notwendig, damit A24 auch für die ROM Dekodierung ausgewertet werden kann. Ansonsten überlappen sich ROM bei 0x0E0++ und das Ende Deines FastRAMS bei 0x1E0++.

Meine letzte U12-Variante mit SRAM ist eine gemeinsame Lösung für SRAM im FastRAM-Bereich und ROM in den vier Sockeln mit dann nur einem GAL, Muss dann aber ein 22V10 sein und einige Signale müssen umgelegt werden, damit alles in ein GAL passt.
Das ist aber für die TT-FastRAM-Version nicht nötig.
Der mindesten Fortschritt, den ich damit erwarte ist, dass Templemon sich nicht mehr aufhängt, dann /DSACKs beim Zugriff aufs FastRAM kommen sollten.
Ob die Daten trotz des eigentlich von der TT-FastRAM-Karte erwarteten synchronen Zugriffs auch korrekt gelesen und geschrieben werden können, steht auf einem anderen Blatt.
Das wäre dann der nächste Schritt.

Was ich nicht kapiere, ist die Bemerkung an Pin 15 (nicht als input nutzbar)
Woher kommt das? ist das originale U12 auch schon ein 22V10? und das (Pin 15 = Input) geht nur mit einem 22V10?
   
« Letzte Änderung: Do 09.03.2017, 17:39:26 von joejoe »

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #112 am: Do 09.03.2017, 16:57:36 »
Ich versuche heute Abend mal DOSBOX unter Windows 7, auf dem Mac komme ich mit der Tastatur nicht klar ...

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #113 am: Do 09.03.2017, 23:13:22 »
Unter Windows will es nicht klappen. Da ist irgendwas mit den config Dateien von PALASM nicht in Ordnung, keine Ahnung ...

Unter macOS geht es jetzt aber, ich nutze einfach ein zusätzliches PC USB Keyboard wegen der Tastaturbelegung.

Aber ich kann kein JED erzeugen, bin zu doof. Muss mich wohl erst durch das Handbuch lesen ...

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #114 am: Do 09.03.2017, 23:23:47 »
Ich habe leider auch keine lauffähige PALASM-Installation zur Hand.

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #115 am: Fr 10.03.2017, 08:08:12 »
Läuft ja, ich bin nur du Dumm dafür ...

In JEDI umsetzen bekomme  ich nicht hin also muss ich mich durch PALASM kämpfen. Bis dahin geht nichts weiter ...
« Letzte Änderung: Fr 10.03.2017, 10:04:37 von Lukas Frank »

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #116 am: Fr 10.03.2017, 11:04:23 »
Welchen Weg verfolgst Du denn eigentlich zur Zeit?
Ein GAL für U12 mit A24 plus die /DSACKs für Deine AtariTT-FastRAM-Karte?
Hast Du eine funktionierende JEDI-Quelle für U12 mit TOS 3.06 in den PAK-Sockeln?

Ich hatte damals immer Zugriff auf PALASM und ALLPROG-Programmer; daher habe ich leider keine Ahnung von JEDI und Atari-GAL-Programmier-Geräten.

Woran hakt es denn (bei JEDI) konkret?
Poste doch mal Deinen aktuellen Stand.

Offline tuxie

  • Benutzer
  • Beiträge: 6.830
  • Falcon! Milan! Schuetzt die Raubvoegel!
Re: Fastram mit PAK68/2 ...
« Antwort #117 am: Fr 10.03.2017, 11:16:59 »
Ich schau mal das ich es dir für jedi heute Abend umsetze, ich hoffe ich schaffe es Zeitmässig
Tschau Ingo

Offline Lukas Frank

  • Benutzer
  • Beiträge: 13.012
  • fancy Atari Musik anDA Dance "Agare Hinu Harukana"
Re: Fastram mit PAK68/2 ...
« Antwort #118 am: Fr 10.03.2017, 11:37:36 »
In #110 ist das JEDI LCI, ist aber auch nicht von mir. Soweit ich weiss kann JEDI nur 16V8 und 20V8, keine 22V10 und kann keine Klammern im Code verarbeiten. Man muss alles einzeln auflösen ...

PALASM ist schon gut, ich muss das nur verstehen. Wenn ich dein p20_24.pds kompilieren will kommt immer das kein Device definiert sei. Ich weiss aber nicht wo ich das angeben sollte ?

Offline joejoe

  • Benutzer
  • Beiträge: 221
Re: Fastram mit PAK68/2 ...
« Antwort #119 am: Fr 10.03.2017, 12:25:35 »
Huh, das ist im letzten Jahrtausend programmiert ;)
Dunkel kann ich mich an eine Auswahl per Cursor aus der Liste der von PALASM unterstützten PALs erinnern. GALs waren schon damals zu neu für PALASM bzw. kamen von einem anderen Hersteller??.
Die Auswahl von PALCE20V8 bzw. PALCE22V10 hat allerdings zum entsprechenden GAL kompatiblem JEDEC-File geführt.

Ich muss 'mal die alte XP-Kiste hervorholen & anwerfen, da hatte ich die letzte lauffähige Version von PALASM drauf.